Palabras clave: unidades, mapeo, tipo
Autor: ¿?

Objetivo
Listar las unidades de nuestro ordenador ya sean físicas, extraíbles o de red para obtener su tipo.


Function TestUnidades()
    Dim objDrv      As Object
    Dim strMsg      As String
 
    For Each objDrv In CreateObject("Scripting.FileSystemObject").Drives
        Select Case objDrv.DriveType
            Case 0: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ": Unknown"
            Case 1: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ": Removable Drive"
            Case 2: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ": Hard Disk Drive"
            Case 3: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ": Network Drive"
            Case 4: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ": CDROM Drive"
            Case 5: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ": RAM Disk Drive"
        End Select
    Next
    Debug.Print strMsg
    Set objDrv = Nothing
End Function


Palabras clave: función, complemento, eval, CodeProject
Autor: Rafael Andrada (McPegasus) sobre idea de Chea
Extraído de: AUGE

---

Situación:
Disponemos de un complemento que tiene un procedimiento. Ese procedimiento debe llamar a otra función dentro del mismo complemento. En ese caso el Eval no funciona. ¿Alternativa?

Dice Chea...
Desde un complemento no puedes ejecutar una función de la aplicación principal, ni con eval, ni directamente. Tienes que usar CurrentProject.Application.Run que, como también es una función, quizás puedas llamarla con Eval.


Y Rafa responde...
Pues solucionado, graaaaaacias. En lugar de Eval, Run y CodeProject en lugar de CurrentProject.

Antes: strValue = Nz(Eval(strFunciónValue))

Ahora: strValue = CodeProject.Application.Run(strFunción, strValue)

Palabras clave: copiar, portapapeles, clipboard
Autor: Mihura

Objetivo:
McPegasus pregunta en un grupo si existen alternativas al SendKeys ( ) para copiar un texto dado en el portapapeles. Apunta 2 soluciones: una mediante API y otra mediante MSForms.DataObject.
Parece ser que la API está fallando últimamente y que la MSForms obliga a tener la referencia (cosa no siempre posible/deseable)

Respuesta
Mihura, casi al límite del tiempo que había marcado, nos obsequia con esta pequeña maravilla de 5 líneas:

Public Function RT_CopyToClip(ByVal Expresion As String)
    Const DATAOBJECT_BINDING As String = "new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}"
    With CreateObject(DATAOBJECT_BINDING)
        .SetText Expresion
        .PutInClipboard
    End With
End Function


Palabras clave: consulta, SQL, referencias, controles
Extraído de: De aquí y de allí

---

Pregunta
¿Cuál es la forma de construir cadenas con criterios de diferentes tipos de datos?

Respuesta
Cuando se construyen cadenas SQL en un formulario es necesario tener presente que:
- Las referencias a valores que se encuentran en controles del formulario dónde se ejecuta el código (ME!...) deben "extraerse" de la cadena
- El tipo de valor que contiene el campo es relevante para delimitar y formatear los datos.
 + los textos se delimitan con comillas... pero dado que las comillas ya están delimitando la propia SQL, lo sustituimos por apóstrofes.
 + los números enteros no se delimitan y no dan ningún problema
 + los números decimales, al utilizar la coma, pueden dar problemas. Por ese motivo podemos utilizar Str
 + las fechas se delimitan con # y se "americanizan"

"SELECT * FROM UnaTabla WHERE UnCampoTexto = '" & Me!UnCampoTexto & "' AND UnCampoEntero = " & Me!UnCampoEntero & " AND UnCampoDecimal = " & Str(Me!UnCampoDecimal) & " AND UnCampoFecha = #" & Format(Me!UnCampoFecha, "mm/dd/yyyy") & "#"

Como siempre, sólo hay que bucear un poco para encontrar una respuesta que mejore ampliamente el rendimiento. Y, como no, la respuesta es de Happy. Utilizando el objeto indocumentado WizHook.

Function whExisteProcedimiento(strProcedure As String) As Boolean
    WizHook.Key = 51488399
    whExisteProcedimiento = WizHook.GlobalProcExists(strProcedure)
End Function