Como siempre, sólo hay que bucear un poco para encontrar una respuesta que mejore ampliamente el rendimiento. Y, como no, la respuesta es de Happy. Utilizando el objeto indocumentado WizHook.

Function whExisteProcedimiento(strProcedure As String) As Boolean
    WizHook.Key = 51488399
    whExisteProcedimiento = WizHook.GlobalProcExists(strProcedure)
End Function


Palabras clave: carpeta, directorio, fichero, archivo, nombre, corto, largo API
Autor: Happy
Extraído de: Access y VBA

Objetivo:
Rescato estos procedimientos de Happy para obtener el nombre corto de fichero a partir del nombre largo y viceversa.


En un módulo independiente:
Option Compare Database
Option Explicit

Private Declare Function GetLongPathName Lib "kernel32" _
                Alias "GetLongPathNameA" _
                (ByVal lpszShortPath As String, _
                ByVal lpszLongPath As String, _
                ByVal cchBuffer As Long) As Long

Private Declare Function GetShortPathName Lib "kernel32" _
                Alias "GetShortPathNameA" _
                (ByVal lpszLongPath As String, _
                ByVal lpszShortPath As String, _
                ByVal lBuffer As Long) As Long

Function GetLongName(ShortPath As String) As String
Dim LenLongName As Long
Dim buffer As String * 1000

    LenLongName = GetLongPathName(ShortPath, _
                          buffer, Len(buffer))
    If LenLongName Then
        GetLongName = Left$(buffer, LenLongName)
    End If

End Function

Function GetShortName(LongPath As String) As String
Dim LenShortName As Long
Dim buffer As String * 1000

    LenShortName = GetShortPathName(LongPath, _
                          buffer, Len(LongPath))
    If LenShortName Then
        GetShortName = Left$(buffer, LenShortName)
    End If

End Function


Palabras clave: Excel, automatización, registros
Autor: Jesus Mansilla (Mihura)

En ocasiones necesitamos leer un fichero Excel mediante automatización y, para poder mostrar "algo" que nos de idea del progreso, es necesario averiguar la cantidad de registros afectados,

Una opción es insertar una fórmula en una celda "lejana" que nos haga un COUNTA (CONTARA) de los registros de una columna que sepamos debe estar toda rellena.

xls.ActiveSheet.Cells(1, 255).FormulaR1C1 = "=COUNTA(C1)
Leer el resultado (restarle 1 si existe una fila de titulos) y eliminar el contenido de la celda. Hay que acordarse de que, al cerrar el Excel, no se guarden los cambios.

Jesus presenta una alternativa:

UltimaFila = xls.ActiveSheet.Cells(xls.ActiveSheet.Rows.Count, 1).End(xlUp).Row
Traducido: posicionarse en la ultima fila de la hoja (ActiveSheet.Rows.Count) en su primera columna (1) y "tirar p'arriba" con .End(xlUp)  (equivalente a Ctrl + flecha arriba). Ello posiciona en la ultima celda escrita de la columna. Y de allí tomamos la fila (.Row)

Lo mismo para las columnas
UltimaColumna = xls.ActiveSheet.Cells(1, xls.ActiveSheet.Columns.Count).End(xlToLeft).Column
Ingenioso.

Palabras clave: listbox, recorrer, multiselección
Autor: Xavi
Extraído de: Harto de buscarlo cuando lo necesito, lo cuelgo aquí

---

Pregunta
¿Cómo puedo recorrer los ítems seleccionados de un cuadro de lista de selección múltiple?

Respuesta
Habitualmente tratamos con los ListBox en modo de selección simple pero, cuando se trata de un ListBox de multiselección, el modo de obtener la lista de valores seleccionados es ligeramente distinto.

Lo que haremos será imaginar un ListBox de 2 columnas dónde la primera está oculta (es el índice) y la segunda es la que muestra la descripción.
Deseamos obtener la lista de índices que se han seleccionado (da lo mismo que sea selección extendida o no) para almacenarlos en una cadena de texto que utilizaremos, por ejemplo, en una cláusula IN de una SQL.


    Dim varitem
    Dim strTmp As String
    Dim strIN    As String
    For Each varitem In Me!cboEjemplo.ItemsSelected
        strTmp = strTmp & ", " & Me!cboEjemplo.Column(0, varitem)
    Next
    strIN = "IN (" & Mid(strTmp, 3) & ")"


Palabras clave: sendkeys, bloqnum
Autor: A mi me lo pasó Mihura

Objetivo:
Emular el funcionamiento de SendKeys de Access pero sin el problema reconocido de activar/desactivar la tecla de bloqueo numérico.

Function fSendKeys(strKey as String)
  Dim ws As Object
  Set ws = CreateObject("WScript.shell")
  ws.SendKeys strKey
  Set ws = Nothing
End Function